CONTENTS

• NAME
• VERSION
• SYNOPSIS
• DESCRIPTION
• PERL VERSION
• METHODS
  • new
  • log
  • log_fatal
  • log_debug
  • log_event
  • log_debug_event
  • set_debug
  • get_debug
  • clear_debug
  • set_muted
  • get_muted
  • clear_muted
  • get_prefix
  • set_prefix
  • clear_prefix
  • ident
  • config_id
  • dispatcher
  • stdio_dispatcher_class
• LOGGER PREFIX
• METHODS FOR SUBCLASSING
  • string_flogger
  • env_prefix
  • env_value
• METHODS FOR TESTING
  • new_tester
  • events
  • clear_events
• METHODS FOR PROXY LOGGERS
  • proxy
  • parent
  • logger
• METHODS FOR API COMPATIBILITY
• SEE ALSO
• AUTHOR
• CONTRIBUTORS
• COPYRIGHT AND LICENSE

#NAME

Log::Dispatchouli - a simple wrapper around Log::Dispatch

#VERSION

version 3.008

#SYNOPSIS

my $logger = Log::Dispatchouli->new({
  ident     => 'stuff-purger',
  facility  => 'daemon',
  to_stdout => $opt->{print},
  debug     => $opt->{verbose}
});

$logger->log([ "There are %s items left to purge...", $stuff_left ]);

$logger->log_debug("this is extra often-ignored debugging log");

$logger->log_fatal("Now we will die!!");

#DESCRIPTION

Log::Dispatchouli is a thin layer above Log::Dispatch and meant to make it dead simple to add logging to a program without having to think much about categories, facilities, levels, or things like that. It is meant to make logging just configurable enough that you can find the logs you want and just easy enough that you will actually log things.

Log::Dispatchouli can log to syslog (if you specify a facility), standard error or standard output, to a file, or to an array in memory. That last one is mostly useful for testing.

In addition to providing as simple a way to get a handle for logging operations, Log::Dispatchouli uses String::Flogger to process the things to be logged, meaning you can easily log data structures. Basically: strings are logged as is, arrayrefs are taken as (sprintf format, args), and subroutines are called only if needed. For more information read the String::Flogger docs.

#PERL VERSION

This library should run on perls released even a long time ago. It should work on any version of perl released in the last five years.

Although it may work on older versions of perl, no guarantee is made that the minimum required version will not be increased. The version may be increased for any reason, and there is no promise that patches will be accepted to lower the minimum required perl.

#METHODS

#new

my $logger = Log::Dispatchouli->new(\%arg);

This returns a new logger, a Log::Dispatchouli object.

Valid arguments are:

ident       - the name of the thing logging (mandatory)
to_self     - log to the logger object for testing; default: false
to_stdout   - log to STDOUT; default: false
to_stderr   - log to STDERR; default: false
facility    - to which syslog facility to send logs; default: none

to_file     - DEPRECATED: this option will be removed in 2025
              log to PROGRAM_NAME.YYYYMMDD in the log path; default: false
log_file    - a leaf name for the file to log to with to_file
log_path    - path in which to log to file; defaults to DISPATCHOULI_PATH
              environment variable or, failing that, to your system's tmpdir

file_format - this optional coderef is passed the message to be logged
              and returns the text to write out

log_pid     - if 1, prefix all log entries with the pid; default: true
              can also be a comma-delimited list of log targets where pid is
              logged, like "stderr,syslog"; mostly useful for logging pid in
              syslog, but not on standard I/O
fail_fatal  - a boolean; if true, failure to log is fatal; default: true
muted       - a boolean; if true, only fatals are logged; default: false
debug       - a boolean; if true, log_debug method is not a no-op
              defaults to the truth of the DISPATCHOULI_DEBUG env var
quiet_fatal - 'stderr' or 'stdout' or an arrayref of zero, one, or both
              fatal log messages will not be logged to these
              (default: stderr)
config_id   - a name for this logger's config; rarely needed!
syslog_socket - a value for Sys::Syslog's "socket" arg; default: "native"

The log path is either /tmp or the value of the DISPATCHOULI_PATH env var.

If the DISPATCHOULI_NOSYSLOG env var is true, we don't log to syslog.

#log

$logger->log(@messages);

$logger->log(\%arg, @messages);

This method uses String::Flogger on the input, then unconditionally logs the result. Each message is flogged individually, then joined with spaces.

If the first argument is a hashref, it will be used as extra arguments to logging. It may include a prefix entry to preprocess the message by prepending a string (if the prefix is a string) or calling a subroutine to generate a new message (if the prefix is a coderef).

#log_fatal

This behaves like the log method, but will throw the logged string as an exception after logging.

This method can also be called as fatal, to match other popular logging interfaces. If you want to override this method, you must override log_fatal and not fatal.

#log_debug

This behaves like the log method, but will only log (at the debug level) if the logger object has its debug property set to true.

This method can also be called as debug, to match other popular logging interfaces. If you want to override this method, you must override log_debug and not debug.

#log_event

This method is like log, but is used for structured logging instead of free form text. It's invoked like this:

$logger->log($event_type => $data_ref);

$event_type should be a simple string, probably a valid identifier, that identifies the kind of event being logged. It is suggested, but not required, that all events of the same type have the same kind of structured data in them.

$data_ref is a set of key/value pairs of data to log in this event. It can be an arrayref (in which case the ordering of pairs is preserved) or a hashref (in which case they are sorted by key).

The logged string will be in logfmt format, meaning a series of key=value pairs separated by spaces and following these rules:

• an "identifier" is a string of printable ASCII characters between ! and ~, excluding \ and =

• keys must be valid identifiers

• if a key is empty, ~ is used instead

• if a key contains characters not permitted in an identifier, they are replaced by ?

• values must either be valid identifiers, or be quoted

• quoted value start and end with "

• in a quoted value, " becomes \", \ becomes \\, newline and carriage return become \n and \r respectively, and other control characters are replaced with \u{....} where the contents of the braces are the hex value of the control character

When values are undef, they are represented as ~.

When values are array references, the index/values are mapped over, so that:

key => [ 'a', 'b' ]

becomes

key.0=a key.1=b

When values are hash references, the key/values are mapped, with keys sorted, so that:

key => { b => 2, a => 1 }

becomes

key.a=1 key.b=2

This expansion is performed recursively. If a value itself recurses, appearances of a reference after the first time will be replaced with a string like &foo.bar, pointing to the first occurrence. This is not meant to be a robust serialization mechanism. It's just here to help you be a little lazy. Don't push the limits.

If the value in $data_ref is a code reference, it will be called and its result logged. If its result is also a code reference, you get whatever garbage that code reference stringifies to.

If the value in $data_ref is a reference reference, then the referenced scalar will be passed to String::Flogger, and the resulting string will be used as the value to log. That string will be quoted as described above, if needed.

#log_debug_event

This method is just like log_event, but will log nothing unless the logger has its debug property set to true.

#set_debug

$logger->set_debug($bool);

This sets the logger's debug property, which affects the behavior of log_debug.

#get_debug

This gets the logger's debug property, which affects the behavior of log_debug.

#clear_debug

This method does nothing, and is only useful for Log::Dispatchouli::Proxy objects. See Methods for Proxy Loggers, below.

#set_muted

$logger->set_muted($bool);

This sets the logger's muted property, which affects the behavior of log.

#get_muted

This gets the logger's muted property, which affects the behavior of log.

#clear_muted

This method does nothing, and is only useful for Log::Dispatchouli::Proxy objects. See Methods for Proxy Loggers, below.

#get_prefix

my $prefix = $logger->get_prefix;

This method returns the currently-set prefix for the logger, which may be a string or code reference or undef. See Logger Prefix.

#set_prefix

$logger->set_prefix( $new_prefix );

This method changes the prefix. See Logger Prefix.

#clear_prefix

This method clears any set logger prefix. (It can also be called as unset_prefix, but this is deprecated. See Logger Prefix.

#ident

This method returns the logger's ident.

#config_id

This method returns the logger's configuration id, which defaults to its ident. This can be used to make two loggers equivalent in Log::Dispatchouli::Global so that trying to reinitialize with a new logger with the same config_id as the current logger will not throw an exception, and will simply do no thing.

#dispatcher

This returns the underlying Log::Dispatch object. This is not the method you're looking for. Move along.

#stdio_dispatcher_class

This method is an experimental feature to allow you to pick an alternate dispatch class for stderr and stdio. By default, Log::Dispatch::Screen is used. This feature may go away at any time.

#LOGGER PREFIX

Log messages may be prepended with information to set context. This can be set at a logger level or per log item. The simplest example is:

my $logger = Log::Dispatchouli->new( ... );

$logger->set_prefix("Batch 123: ");

$logger->log("begun processing");

# ...

$logger->log("finished processing");

The above will log something like:

Batch 123: begun processing
Batch 123: finished processing

To pass a prefix per-message:

$logger->log({ prefix => 'Sub-Item 234: ' }, 'error!')

# Logs: Batch 123: Sub-Item 234: error!

If the prefix is a string, it is prepended to each line of the message. If it is a coderef, it is called and passed the message to be logged. The return value is logged instead.

Proxy loggers also have their own prefix settings, which accumulate. So:

my $proxy = $logger->proxy({ proxy_prefix => 'Subsystem 12: ' });

$proxy->set_prefix('Page 9: ');

$proxy->log({ prefix => 'Paragraph 6: ' }, 'Done.');

...will log...

Batch 123: Subsystem 12: Page 9: Paragraph 6: Done.

#METHODS FOR SUBCLASSING

#string_flogger

This method returns the thing on which flog will be called to format log messages. By default, it just returns String::Flogger

#env_prefix

This method should return a string used as a prefix to find environment variables that affect the logger's behavior. For example, if this method returns XYZZY then when checking the environment for a default value for the debug parameter, Log::Dispatchouli will first check XYZZY_DEBUG, then DISPATCHOULI_DEBUG.

By default, this method returns (), which means no extra environment variable is checked.

#env_value

my $value = $logger->env_value('DEBUG');

This method returns the value for the environment variable suffix given. For example, the example given, calling with DEBUG will check DISPATCHOULI_DEBUG.

#METHODS FOR TESTING

#new_tester

my $logger = Log::Dispatchouli->new_tester( \%arg );

This returns a new logger that logs only to_self. It's useful in testing. If no ident arg is provided, one will be generated. log_pid is off by default, but can be overridden.

\%arg is optional.

#events

This method returns the arrayref of events logged to an array in memory (in the logger). If the logger is not logging to_self this raises an exception.

#clear_events

This method empties the current sequence of events logged into an array in memory. If the logger is not logging to_self this raises an exception.

#METHODS FOR PROXY LOGGERS

#proxy

my $proxy_logger = $logger->proxy( \%arg );

This method returns a new proxy logger -- an instance of Log::Dispatchouli::Proxy -- which will log through the given logger, but which may have some settings localized.

%arg is optional. It may contain the following entries:

#proxy_prefix

This is a prefix that will be applied to anything the proxy logger logs, and cannot be changed.

#proxy_ctx

This is data to be inserted in front of event data logged through the proxy. It will appear after the event key but before the logged event data. It can be in the same format as the $data_ref argument to log_event.

#debug

This can be set to true or false to change the proxy's "am I in debug mode?" setting. It can be changed or cleared later on the proxy.

#parent

#logger

These methods return the logger itself. (They're more useful when called on proxy loggers.)

#METHODS FOR API COMPATIBILITY

To provide compatibility with some other loggers, most specifically Log::Contextual, the following methods are provided. You should not use these methods without a good reason, and you should never subclass them. Instead, subclass the methods they call.

#is_debug

This method calls get_debug.

#is_info

#is_fatal

These methods return true.

#info

#fatal

#debug

These methods redispatch to log, log_fatal, and log_debug respectively.

#SEE ALSO

• Log::Dispatch

• String::Flogger

#AUTHOR

Ricardo SIGNES <cpan@semiotic.systems>

#CONTRIBUTORS

• Charlie Garrison <cng@garrison.com.au>

• Christopher J. Madsen <perl@cjmweb.net>

• Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>

• Dan Book <grinnz@gmail.com>

• George Hartzell <hartzell@alerce.com>

• Jon Stuart <jon@fastmailteam.com>

• Matt Phillips <mattp@cpan.org>

• Olivier Mengué <dolmen@cpan.org>

• Randy Stauner <randy@magnificent-tears.com>

• Ricardo Signes <rjbs@semiotic.systems>

• Ricardo Signes <rjbs@users.noreply.github.com>

• Sawyer X <xsawyerx@cpan.org>

#COPYRIGHT AND LICENSE

This software is copyright (c) 2024 by Ricardo SIGNES.

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

CPANdoc Browser is maintained by Dan Book (DBOOK). Please contact him via the GitHub issue tracker or email regarding any issues with the site itself, search, or rendering of documentation.

CPAN module documentation is maintained by each author and maintainer individually. Please contact them via the mechanisms listed in their documentation or on the module's MetaCPAN page to report any issues with the contents or format of the documentation.